Jump to content

  2. →
  3. →

Photo

Size, Width, Height

Started By gnomo, 26/07/2003, 19:36

  • Faça o login para participar
7 replies to this topic

#1 gnomo

gnomo

    Novato no fórum

  • Usuários
  • 23 posts
  • Sexo:Não informado

Posted 26/07/2003, 19:36

Como faço pra exibir o tamanho, a altura e a largura de uma imagem, por exemplo.
+ NOME - Tiago Monteiro Loeblein
+ E-MAIL - gnomo88@bol.com.br
+ SITE - www.superservicos.kit.net

#2 dmaneiro

dmaneiro

    Normal

  • Usuários
  • 62 posts
  • Sexo:Não informado

Posted 26/07/2003, 21:41

eh soh tu ter salvo no banco a largura, a altura e o tamanho.. ae tu vai bota
height="<%=objrs("height")%>"; width="<%=objrs("width")%>"; size="<%=objrs("size")%>"...
certu falow <%=tiago("gnomo")%> :lol:
<%
nick = "Dmaneiro"
sou = "Web Master e Web Designer"
programas = "FW , FL , DW , FH e PS"
moro_em = "Novo Hamburgo/RS[/color]"
site = WS - Web Solutions

response.write(nick & sou & programas & moro_em & site)
%>

#3 gnomo

gnomo

    Novato no fórum

  • Usuários
  • 23 posts
  • Sexo:Não informado

Posted 29/08/2003, 10:50

Não é assim!

Igual o do aspecto, qd o cara faz o upload mostra o tamanho da arquivo.

Valeu! :ok:
+ NOME - Tiago Monteiro Loeblein
+ E-MAIL - gnomo88@bol.com.br
+ SITE - www.superservicos.kit.net

#4 cybermix

cybermix

    andrewsmedina.com.br

  • Ex-Admins
  • 3586 posts
  • Sexo:Não informado
  • Localidade:Não sou desse planeta não!!!!
  • Interesses:python, fireworks, linux, php, flash...

Posted 29/08/2003, 10:56

ai vai um codigo, q mostra a largura, a altura e o tamanho da imagem feito com fso

<%
'###############################################
' Este é o teste... coloque qualquer GIF nesta pasta
' E você verá o milagre acontecendo!
' Pode tambem ser com qualquer extensão lembrando
' Somente de mudar no IF ou então adapta-lo para ler
' Qualquer tipo de Arquivo, você pode usar um case!
' se for o caso !!! hehehh
'###############################################
  Set objFSO = CreateObject("Scripting.FileSystemObject")
  Set objF = objFSO.GetFolder("c:\inetpub\wwwroot\minhaimagens")
  Set objFC = objF.Files

  response.write "<table border=""0"" cellpadding=""5"">"

  For Each f1 in objFC
    if instr(ucase(f1.Name), ".JPG") then
       response.write "<tr><td>" & f1.name & "</td><td>" & f1.DateCreated & "</td><td>" & f1.Size & "</td><td>"

       if gfxSpex(f1.Path, w, h, c, strType) = true then
          response.write w & " x " & h & " " & c & " colors"
       else
          response.write "&nbsp;"
       end if

       response.write "</td></tr>"

    end if

  Next

  response.write "</table>"

  set objFC = nothing
  set objF = nothing
  set objFSO = nothing

'##############################################

  function GetBytes(flnm, offset, bytes)

     Dim objFSO
     Dim objFTemp
     Dim objTextStream
     Dim lngSize

     on error resume next

     Set objFSO = CreateObject("Scripting.FileSystemObject")
     
     ' First, we get the filesize
     Set objFTemp = objFSO.GetFile(flnm)
     lngSize = objFTemp.Size
     set objFTemp = nothing

     fsoForReading = 1
     Set objTextStream = objFSO.OpenTextFile(flnm, fsoForReading)

     if offset > 0 then
        strBuff = objTextStream.Read(offset - 1)
     end if

     if bytes = -1 then  ' Get All!

        GetBytes = objTextStream.Read(lngSize)  'ReadAll

     else

        GetBytes = objTextStream.Read(bytes)

     end if

     objTextStream.Close
     set objTextStream = nothing
     set objFSO = nothing

  end function


  function lngConvert(strTemp)
     lngConvert = clng(asc(left(strTemp, 1)) + ((asc(right(strTemp, 1)) * 256)))
  end function

  function lngConvert2(strTemp)
     lngConvert2 = clng(asc(right(strTemp, 1)) + ((asc(left(strTemp, 1)) * 256)))
  end function


  function gfxSpex(flnm, width, height, depth, strImageType)

     dim strPNG 
     dim strGIF
     dim strBMP
     dim strType
     strType = ""
     strImageType = "(unknown)"

     gfxSpex = False

     strPNG = chr(137) & chr(80) & chr(78)
     strGIF = "GIF"
     strBMP = chr(66) & chr(77)

     strType = GetBytes(flnm, 0, 3)

     if strType = strGIF then    ' is GIF

        strImageType = "GIF"
        Width = lngConvert(GetBytes(flnm, 7, 2))
        Height = lngConvert(GetBytes(flnm, 9, 2))
        Depth = 2 ^ ((asc(GetBytes(flnm, 11, 1)) and 7) + 1)
        gfxSpex = True

     elseif left(strType, 2) = strBMP then  ' is BMP

        strImageType = "BMP"
        Width = lngConvert(GetBytes(flnm, 19, 2))
        Height = lngConvert(GetBytes(flnm, 23, 2))
        Depth = 2 ^ (asc(GetBytes(flnm, 29, 1)))
        gfxSpex = True

     elseif strType = strPNG then   ' Is PNG

        strImageType = "PNG"
        Width = lngConvert2(GetBytes(flnm, 19, 2))
        Height = lngConvert2(GetBytes(flnm, 23, 2))
        Depth = getBytes(flnm, 25, 2)

        select case asc(right(Depth,1))
           case 0
              Depth = 2 ^ (asc(left(Depth, 1)))
              gfxSpex = True
           case 2
              Depth = 2 ^ (asc(left(Depth, 1)) * 3)
              gfxSpex = True
           case 3
              Depth = 2 ^ (asc(left(Depth, 1)))  '8
              gfxSpex = True
           case 4
              Depth = 2 ^ (asc(left(Depth, 1)) * 2)
              gfxSpex = True
           case 6
              Depth = 2 ^ (asc(left(Depth, 1)) * 4)
              gfxSpex = True
           case else
              Depth = -1
        end select


     else

        strBuff = GetBytes(flnm, 0, -1)  ' Get all bytes from file
        lngSize = len(strBuff)
        flgFound = 0

        strTarget = chr(255) & chr(216) & chr(255)
        flgFound = instr(strBuff, strTarget)

        if flgFound = 0 then
           exit function
        end if

        strImageType = "JPG"
        lngPos = flgFound + 2
        ExitLoop = false

        do while ExitLoop = False and lngPos < lngSize

           do while asc(mid(strBuff, lngPos, 1)) = 255 and lngPos < lngSize
              lngPos = lngPos + 1
           loop

           if asc(mid(strBuff, lngPos, 1)) < 192 or asc(mid(strBuff, lngPos, 1)) > 195 then
              lngMarkerSize = lngConvert2(mid(strBuff, lngPos + 1, 2))
              lngPos = lngPos + lngMarkerSize  + 1
           else
              ExitLoop = True
 &njsp;         end if

       loop
       '
       if ExitLoop = False then

          Width = -1
          Height = -1
          Depth = -1

       else

          Height = lngConvert2(mid(strBuff, lngPos + 4, 2))
          Width = lngConvert2(mid(strBuff, lngPos + 6, 2))
          Depth = 2 ^ (asc(mid(strBuff, lngPos + 8, 1)) * 8)
          gfxSpex = True

       end if
                   
     end if

  end function
%>

www.andrewsmedina.com.br

#5 gnomo

gnomo

    Novato no fórum

  • Usuários
  • 23 posts
  • Sexo:Não informado

Posted 12/09/2003, 09:24 

ai vai um codigo, q mostra a largura, a altura e o tamanho da imagem feito com fso

CODE  

<%
'###############################################
' Este é o teste... coloque qualquer GIF nesta pasta
' E você verá o milagre acontecendo!
' Pode tambem ser com qualquer extensão lembrando
' Somente de mudar no IF ou então adapta-lo para ler
' Qualquer tipo de Arquivo, você pode usar um case!
' se for o caso !!! hehehh
'###############################################
 Set objFSO = CreateObject("Scripting.FileSystemObject")
 Set objF = objFSO.GetFolder("c:\inetpub\wwwroot\minhaimagens")
 Set objFC = objF.Files

 response.write "<table border=""0"" cellpadding=""5"">"

 For Each f1 in objFC
   if instr(ucase(f1.Name), ".JPG") then
      response.write "<tr><td>" & f1.name & "</td><td>" & f1.DateCreated & "</td><td>" & f1.Size & "</td><td>"

      if gfxSpex(f1.Path, w, h, c, strType) = true then
         response.write w & " x " & h & " " & c & " colors"
      else
         response.write "&nbsp;"
      end if

      response.write "</td></tr>"

   end if

 Next

 response.write "</table>"

 set objFC = nothing
 set objF = nothing
 set objFSO = nothing

'##############################################

 function GetBytes(flnm, offset, bytes)

    Dim objFSO
    Dim objFTemp
    Dim objTextStream
    Dim lngSize

    on error resume next

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    ' First, we get the filesize
    Set objFTemp = objFSO.GetFile(flnm)
    lngSize = objFTemp.Size
    set objFTemp = nothing

    fsoForReading = 1
    Set objTextStream = objFSO.OpenTextFile(flnm, fsoForReading)

    if offset > 0 then
       strBuff = objTextStream.Read(offset - 1)
    end if

    if bytes = -1 then  ' Get All!

       GetBytes = objTextStream.Read(lngSize)  'ReadAll

    else

       GetBytes = objTextStream.Read(bytes)

    end if

    objTextStream.Close
    set objTextStream = nothing
    set objFSO = nothing

 end function


 function lngConvert(strTemp)
    lngConvert = clng(asc(left(strTemp, 1)) + ((asc(right(strTemp, 1)) * 256)))
 end function

 function lngConvert2(strTemp)
    lngConvert2 = clng(asc(right(strTemp, 1)) + ((asc(left(strTemp, 1)) * 256)))
 end function


 function gfxSpex(flnm, width, height, depth, strImageType)

    dim strPNG 
    dim strGIF
    dim strBMP
    dim strType
    strType = ""
    strImageType = "(unknown)"

    gfxSpex = False

    strPNG = chr(137) & chr(80) & chr(78)
    strGIF = "GIF"
    strBMP = chr(66) & chr(77)

    strType = GetBytes(flnm, 0, 3)

    if strType = strGIF then    ' is GIF

       strImageType = "GIF"
       Width = lngConvert(GetBytes(flnm, 7, 2))
       Height = lngConvert(GetBytes(flnm, 9, 2))
       Depth = 2 ^ ((asc(GetBytes(flnm, 11, 1)) and 7) + 1)
       gfxSpex = True

    elseif left(strType, 2) = strBMP then  ' is BMP

       strImageType = "BMP"
       Width = lngConvert(GetBytes(flnm, 19, 2))
       Height = lngConvert(GetBytes(flnm, 23, 2))
       Depth = 2 ^ (asc(GetBytes(flnm, 29, 1)))
       gfxSpex = True

    elseif strType = strPNG then   ' Is PNG

       strImageType = "PNG"
       Width = lngConvert2(GetBytes(flnm, 19, 2))
       Height = lngConvert2(GetBytes(flnm, 23, 2))
       Depth = getBytes(flnm, 25, 2)

       select case asc(right(Depth,1))
          case 0
             Depth = 2 ^ (asc(left(Depth, 1)))
             gfxSpex = True
          case 2
             Depth = 2 ^ (asc(left(Depth, 1)) * 3)
             gfxSpex = True
          case 3
             Depth = 2 ^ (asc(left(Depth, 1)))  '8
             gfxSpex = True
          case 4
             Depth = 2 ^ (asc(left(Depth, 1)) * 2)
             gfxSpex = True
          case 6
             Depth = 2 ^ (asc(left(Depth, 1)) * 4)
             gfxSpex = True
          case else
             Depth = -1
       end select


    else

       strBuff = GetBytes(flnm, 0, -1)  ' Get all bytes from file
       lngSize = len(strBuff)
       flgFound = 0

       strTarget = chr(255) & chr(216) & chr(255)
       flgFound = instr(strBuff, strTarget)

       if flgFound = 0 then
          exit function
       end if

       strImageType = "JPG"
       lngPos = flgFound + 2
       ExitLoop = false

       do while ExitLoop = False and lngPos < lngSize

          do while asc(mid(strBuff, lngPos, 1)) = 255 and lngPos < lngSize
             lngPos = lngPos + 1
          loop

          if asc(mid(strBuff, lngPos, 1)) < 192 or asc(mid(strBuff, lngPos, 1)) > 195 then
             lngMarkerSize = lngConvert2(mid(strBuff, lngPos + 1, 2))
             lngPos = lngPos + lngMarkerSize  + 1
          else
             ExitLoop = True
&njsp;         end if

      loop
      '
      if ExitLoop = False then

         Width = -1
         Height = -1
         Depth = -1

      else

         Height = lngConvert2(mid(strBuff, lngPos + 4, 2))
         Width = lngConvert2(mid(strBuff, lngPos + 6, 2))
         Depth = 2 ^ (asc(mid(strBuff, lngPos + 8, 1)) * 8)
         gfxSpex = True

      end if
                  
    end if

 end function
%>


valeu pelo código :ok:
+ NOME - Tiago Monteiro Loeblein
+ E-MAIL - gnomo88@bol.com.br
+ SITE - www.superservicos.kit.net

#6 gnomo

gnomo

    Novato no fórum

  • Usuários
  • 23 posts
  • Sexo:Não informado

Posted 12/09/2003, 09:26

Ainda naum pude testa o codigo pois ao testar no aspecto fiquei bloqueado por 4 dias por desrespeitar as regras com este código, mas mesmo assim valeu! :ok:
+ NOME - Tiago Monteiro Loeblein
+ E-MAIL - gnomo88@bol.com.br
+ SITE - www.superservicos.kit.net

#7 cybermix

cybermix

    andrewsmedina.com.br

  • Ex-Admins
  • 3586 posts
  • Sexo:Não informado
  • Localidade:Não sou desse planeta não!!!!
  • Interesses:python, fireworks, linux, php, flash...

Posted 12/09/2003, 09:27

Ainda naum pude testa o codigo pois ao testar no aspecto fiquei bloqueado por 4 dias por desrespeitar as regras com este código, mas mesmo assim valeu! :ok:

é que o aspecto nao aceita file system object
www.andrewsmedina.com.br

#8 gnomo

gnomo

    Novato no fórum

  • Usuários
  • 23 posts
  • Sexo:Não informado

Posted 12/09/2003, 09:39

QUOTE (gnomo @ 12 Sep 2003, 08:26)
Ainda naum pude testa o codigo pois ao testar no aspecto fiquei bloqueado por 4 dias por desrespeitar as regras com este código, mas mesmo assim valeu! 

é que o aspecto nao aceita file system object


eu sabia mas eu naum me lembrei disso e como eu ja tinha infringido as regras varioas vezes antes agora tomei ... :ok:
+ NOME - Tiago Monteiro Loeblein
+ E-MAIL - gnomo88@bol.com.br
+ SITE - www.superservicos.kit.net
Voltar para ASP


1 user(s) are reading this topic

0 membro(s), 1 visitante(s) e 0 membros anônimo(s)

  1. Fórum WMO
  2. → Desenvolvimento
  3. → ASP
  4. Privacy Policy
  5. Regras ·
IPB Skin By Virteq